Contents

[DAX USED IN Tbl\_Measure Table 1](#_Toc209904921)

[DAX for Creating Date Table 5](#_Toc209904922)

[DAX for Creating RFM Calculation Table 6](#_Toc209904923)

[DAX Calc Column within RFM Calculation Table 6](#_Toc209904924)

# DAX USED IN Tbl\_Measure Table

**MaxOrderDate =** MAX('Superstore 2025'[Order Date])

**Total Customers =** DISTINCTCOUNT('Superstore 2025'[Customer ID])

**Total Sales =** SUM('Superstore 2025'[Sales])

**AvgRecency =** AVERAGE(RFM\_Calculation[Recency])

**AvgFrequency =** AVERAGE(RFM\_Calculation[Frequency])

**AvgMonetary =** AVERAGE(RFM\_Calculation[Monetary])

**YoY FrequencyVar =**

 VAR LY = CALCULATE([AvgFrequency], SAMEPERIODLASTYEAR(DateTable[Date]))

 VAR LYFormatted = FORMAT(LY, "#,0")

 var yoyCalc = DIVIDE(([AvgFrequency] - LY) , LY)

 var yoyCalcFormatted = FORMAT(yoyCalc,"0.0%;(0.0%)")

RETURN

 SWITCH(

    True(),

    yoyCalc >0, UNICHAR(9650) & " " & yoyCalcFormatted & " | LY " & LYFormatted,

    ISBLANK(LY), UNICHAR(8211) & " | No Data for Last Year ",

    UNICHAR(9660) & " " & yoyCalcFormatted  & " | LY " & LYFormatted

 )

**YoY MonetaryVar =**

 VAR LY = CALCULATE([AvgMonetary], SAMEPERIODLASTYEAR(DateTable[Date]))

 VAR LYFormatted = FORMAT(LY/1000, "$#,0.00") & "K"

 var yoyCalc = DIVIDE(([AvgMonetary] - LY) , LY)

 var yoyCalcFormatted = FORMAT(yoyCalc,"0.0%;(0.0%)")

RETURN

 SWITCH(

    True(),

    yoyCalc >0, UNICHAR(9650) & " " & yoyCalcFormatted & " | LY " & LYFormatted,

    ISBLANK(LY), UNICHAR(8211) & " | No Data for Last Year ",

    UNICHAR(9660) & " " & yoyCalcFormatted  & " | LY " & LYFormatted

 )

**YoY RecencyVar =**

 VAR LY = CALCULATE([AvgRecency], SAMEPERIODLASTYEAR(DateTable[Date]))

 VAR LYFormatted = FORMAT(LY, "#,0")

 var yoyCalc = DIVIDE(([AvgRecency] - LY) , LY)

 var yoyCalcFormatted = FORMAT(yoyCalc,"0.0%;(0.0%)")

RETURN

 SWITCH(

    True(),

    yoyCalc >0, UNICHAR(9650) & " " & yoyCalcFormatted & " | LY " & LYFormatted,

    ISBLANK(LY), UNICHAR(8211) & " | No Data for Last Year ",

    UNICHAR(9660) & " " & yoyCalcFormatted  & " | LY " & LYFormatted

 )

**YoY SalesVariance =**

 VAR LY = CALCULATE([Total Sales], SAMEPERIODLASTYEAR(DateTable[Date]))

 VAR LYFormatted = FORMAT(LY/1000, "$#,0") & "K"

 VAR yoyCalc = DIVIDE([Total Sales] - LY, LY)

 VAR yoyCalcFormatted = FORMAT(yoyCalc, "0.0%; (0.0%)")

 RETURN

  SWITCH(

    TRUE(),

    yoyCalc > 0, UNICHAR(9650) & " " & yoyCalcFormatted & " | LY " & LYFormatted,

    ISBLANK(LY), UNICHAR(8211) & " | No Data for Last Year",

    yoyCalc = 0, UNICHAR(8211) & " | No Change from Last Year",

    UNICHAR(9660) & " " & yoyCalcFormatted & " | LY " & LYFormatted)

**FrequencyYoYColor =**

 VAR LY = CALCULATE([AvgFrequency],SAMEPERIODLASTYEAR(DateTable[Date]))

 VAR YOY = DIVIDE([AvgFrequency] - LY ,LY)

RETURN

 SWITCH(TRUE(),

    YOY > 0, "#00B200",

    OR(ISBLANK(LY), LY=0),"Orange", "#FF0000")

**monetaryYoYColor =**

VAR LY = CALCULATE([AvgMonetary],SAMEPERIODLASTYEAR(DateTable[Date]))

VAR YOY = DIVIDE([AvgMonetary] - LY ,LY)

RETURN

SWITCH(TRUE(),

YOY > 0, "#00B200",

OR(ISBLANK(LY),LY=0),"Orange", "#FF0000")

**recencyYoYColor =**

 VAR LY = CALCULATE([AvgRecency],SAMEPERIODLASTYEAR(DateTable[Date]))

 VAR YOY = DIVIDE([AvgRecency] - LY ,LY)

RETURN

 SWITCH(TRUE(),

    YOY > 0, "#00B200",

    OR(ISBLANK(LY), LY = 0),"Orange", "#FF0000")

**salesYoYColor =**

 VAR LY = CALCULATE([Total Sales], SAMEPERIODLASTYEAR(DateTable[Date]))

 VAR YOY = DIVIDE([Total Sales] - LY, LY)

 RETURN

  SWITCH(TRUE(),

    YOY > 0, "#00B200",

    OR(ISBLANK(LY),LY=0), "Orange", "#FF0000")

# DAX for Creating Date Table

**DateTable =**

ADDCOLUMNS (

    CALENDAR (DATE(2021,1,1), DATE(2025,12,31)),  -- adjust start and end dates

    "Year", YEAR([Date]),

    "Month Number", MONTH([Date]),

    "Month Name", FORMAT([Date], "MMMM"),

    "Year-Month", FORMAT([Date], "YYYY-MM"),

    "Quarter", "Q" & FORMAT([Date], "Q"),

    "Day", DAY([Date]),

    "Day of Week", WEEKDAY([Date], 2),   -- 1 = Sunday start, 2 = Monday start

    "Day Name", FORMAT([Date], "dddd"),

    "Week Number", WEEKNUM([Date], 2)

)

# DAX for Creating RFM Calculation Table

**RFM\_Calculation =**

 SUMMARIZE(

    'Superstore 2025',

    'Superstore 2025'[Customer ID],

    'Superstore 2025'[Customer Name],

    "Recency", DATEDIFF(

        CALCULATE(MAX('Superstore 2025'[Order Date])),

        CALCULATE(MAX('Superstore 2025'[Order Date]), ALL('Superstore 2025')), DAY),

    "Frequency", DISTINCTCOUNT('Superstore 2025'[Order ID]),

    "Monetary", SUM('Superstore 2025'[Sales]))

# DAX Calc Column within RFM Calculation Table

**Frequency\_Score =**

 VAR RankFreq =

  RANKX(

     ALL(RFM\_Calculation),

     RFM\_Calculation[Frequency],,DESC

  )

 VAR TotalCust = COUNTROWS(ALL(RFM\_Calculation))

 RETURN

 CEILING(DIVIDE(RankFreq \* 5, TotalCust),1)

**Monetary\_Score =**

VAR RankMon =

    RANKX (

        ALL ( RFM\_Calculation ),

        RFM\_Calculation[Monetary],

        ,

        DESC

    )

VAR TotalCust = COUNTROWS ( ALL ( RFM\_Calculation ) )

RETURN

CEILING ( DIVIDE ( RankMon \* 5, TotalCust ), 1 )

**Recency\_Score =**

 var RankRecency =

   RANKX(

      ALL(RFM\_Calculation),

      RFM\_Calculation[Recency],,ASC)

 var TotalCust = COUNTROWS(ALL(RFM\_Calculation))

 RETURN

 CEILING(DIVIDE(RankRecency \* 5, TotalCust),1)

**Customer\_Segment =**

SWITCH (

    TRUE (),

    -- Champions: best across recency, frequency, and monetary

    RFM\_Calculation[Recency\_Score] <= 2 &&

    RFM\_Calculation[Frequency\_Score] <= 2 &&

    RFM\_Calculation[Monetary\_Score] <= 2, "Champions",

    -- Loyal Customers: frequent buyers, fairly recent

    RFM\_Calculation[Frequency\_Score] <= 2 &&

    RFM\_Calculation[Recency\_Score] <= 3, "Loyal Customers",

    -- Big Spenders: high monetary value, but not recent

    RFM\_Calculation[Monetary\_Score] <= 2 &&

    RFM\_Calculation[Recency\_Score] >= 3, "Big Spenders",

    -- At Risk: were good before, but haven’t purchased recently

    RFM\_Calculation[Recency\_Score] >= 3 &&

    RFM\_Calculation[Frequency\_Score] <= 3, "At Risk",

    -- Lost: weak in all 3 metrics

    RFM\_Calculation[Recency\_Score] = 5 &&

    RFM\_Calculation[Frequency\_Score] = 5 &&

    RFM\_Calculation[Monetary\_Score] = 5, "Lost",

    -- Default bucket

    "Others"

)